本笔记作为《Shader入门精要》的部分要点回顾和补充

Shader中的光照模型

1、Lambert光照模型

Shader "Custom/Lambert"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            // 声明包含灯光变量的文件
            #include "UnityLightingCommon.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 dif : COLOR0;
            };

            fixed4 _MainColor;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                // 法线向量
                float3 n = UnityObjectToWorldNormal(v.normal);
                n = normalize(n);

                // 灯光方向向量
                fixed3 l = normalize(_WorldSpaceLightPos0.xyz);
                
                // 按照公式计算漫反射
                fixed ndotl = dot(n, l);
                o.dif = _LightColor0 * _MainColor * saturate(ndotl);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return i.dif;
            }
            ENDCG
        }
    }
}

2、Half-Lambert光照模型

Shader "Custom/Half-Lambert"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 dif : COLOR0;
            };

            fixed4 _MainColor;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                float3 n = UnityObjectToWorldNormal(v.normal);
                n= normalize(n);
                fixed3 l = normalize(_WorldSpaceLightPos0).xyz;
                
                fixed ndotl = dot(n, l);
                o.dif = _LightColor0 * _MainColor * (0.5 * ndotl + 0.5);

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return i.dif;
            }
            ENDCG
        }
    }
}

3、Phong光照模型

Shader "Custom/Phong"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
        _SpecularColor ("Specular Color", Color) = (0, 0, 0, 0)
        _Shininess ("Shininess", Range(1, 100)) = 1
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR0;
            };

            fixed4 _MainColor;
            fixed4 _SpecularColor;
            half _Shininess;		

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                // 计算公式中的所有变量
                float3 n = UnityObjectToWorldNormal(v.normal);
                n = normalize(n);
                fixed3 l = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 view = normalize(WorldSpaceViewDir(v.vertex));

                // 漫反射部分
                fixed ndotl = saturate(dot(n, l));
                fixed4 dif = _LightColor0 * _MainColor * ndotl;

                // 镜面反射部分
                float3 ref = reflect(-l, n);
                ref = normalize(ref);
                fixed rdotv = saturate(dot(ref, view));
                fixed4 spec = _LightColor0 * _SpecularColor
                        * pow(rdotv, _Shininess);

                // 环境光+漫反射+镜面反射
                o.color = unity_AmbientSky + dif + spec;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return i.color;
            }
            ENDCG
        }
    }
}

4、逐像素光照

Shader "Custom/per-pixel Phong"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
        _SpecularColor ("Specular Color", Color) = (0, 0, 0, 0)
        _Shininess ("Shininess", Range(1, 100)) = 1
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 normal : TEXCOORD0;
                float4 vertex : TEXCOORD1;
            };

            fixed4 _MainColor;
            fixed4 _SpecularColor;
            half _Shininess;		

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.normal = v.normal;
                o.vertex = v.vertex;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // 计算公式中的所有变量
                float3 n = UnityObjectToWorldNormal(i.normal);
                n = normalize(n);
                fixed3 l = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 view = normalize(WorldSpaceViewDir(i.vertex));

                // 漫反射部分
                fixed ndotl = saturate(dot(n, l));
                fixed4 dif = _LightColor0 * _MainColor * ndotl;

                // 镜面反射部分
                float3 ref = reflect(-l, n);
                ref = normalize(ref);
                fixed rdotv = saturate(dot(ref, view));
                fixed4 spec = _LightColor0 * _SpecularColor
                        * pow(rdotv, _Shininess);

                // 环境光+漫反射+镜面反射
                return unity_AmbientSky + dif + spec;
            }
            ENDCG
        }
    }
}

5、Blinn-Phong模型

Shader "Custom/Blinn-Phong"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
        _SpecularColor ("Specular Color", Color) = (0, 0, 0, 0)
        _Shininess ("Shininess", Range(1, 100)) = 1
    }
    SubShader
    {
        Pass
        {
            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"
            #include "Lighting.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                fixed4 color : COLOR0;
            };

            fixed4 _MainColor;
            fixed4 _SpecularColor;
            half _Shininess;		

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);

                // 计算公式中的所有变量
                fixed3 n = normalize(v.normal);
                fixed3 l = normalize(_WorldSpaceLightPos0.xyz);
                fixed3 view = normalize(WorldSpaceViewDir(v.vertex));
                fixed3 h = normalize(view + l);

                // 漫反射部分
                fixed ndotl = saturate(dot(n, l));
                fixed4 dif = _LightColor0 * _MainColor * ndotl;

                // 镜面反射部分
                fixed ndoth = saturate(dot(n, l));
                fixed4 spec = _LightColor0 * _SpecularColor
                                * pow(ndoth, _Shininess);

                // 环境光+漫反射+镜面反射
                o.color = unity_AmbientSky + dif + spec;

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                return i.color;
            }
            ENDCG
        }
    }
}

6、实现阴影效果

Shader "Custom/Shadow Shader"
{
    Properties
    {
        _MainColor ("Main Color", Color) = (1, 1, 1, 1)
    }
    SubShader
    {
        // -------- 基础Pass 为主要平行光产生投影 --------
        Pass
        {
            // 添加Pass标签
            Tags{"LightMode" = "ForwardBase"}

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdbase
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 normal : TEXCOORD0;
                float4 vertex : TEXCOORD1;
                SHADOW_COORDS(2) // 使用预定义宏保存阴影坐标
            };

            fixed4 _MainColor;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.normal = v.normal;
                o.vertex = v.vertex;
                TRANSFER_SHADOW(o) // 使用预定义宏变换阴影坐标

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // 准备变量
                float3 n = UnityObjectToWorldNormal(i.normal);
                n = normalize(n);
                float3 l = WorldSpaceLightDir(i.vertex);
                l = normalize(l);
                float4 worldPos = mul(unity_ObjectToWorld, i.vertex);

                // Lambert光照
                fixed ndotl = saturate(dot(n, l));
                fixed4 color = _LightColor0 * _MainColor * ndotl;

                // 加上4个点光源的光照
                color.rgb += Shade4PointLights(
                unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
                unity_LightColor[0].rgb, unity_LightColor[1].rgb,
                unity_LightColor[2].rgb, unity_LightColor[3].rgb,
                unity_4LightAtten0, worldPos.rgb, n) * _MainColor;

                // 加上环境光照
                color += unity_AmbientSky;
                
                // 使用预定义宏计算阴影系数
                UNITY_LIGHT_ATTENUATION(shadowmask, i, worldPos.rgb)

                // 阴影合成
                color.rgb *= shadowmask;

                return color;
            }
            ENDCG
        }

        // -------- 额外的Pass 为其他逐像素的灯光产生投影 --------
        Pass
        {
            Tags{"LightMode" = "ForwardAdd"}

            // 使用相加混合，使绘制的图像与上一个Pass完全混合
            Blend One One

            CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma multi_compile_fwdadd_fullshadows
            #include "UnityCG.cginc"
            #include "Lighting.cginc"
            #include "AutoLight.cginc"

            struct v2f
            {
                float4 pos : SV_POSITION;
                float3 normal : TEXCOORD0;
                float4 vertex : TEXCOORD1;
                SHADOW_COORDS(2) // 使用预定义宏保存阴影坐标
            };

            fixed4 _MainColor;

            v2f vert (appdata_base v)
            {
                v2f o;
                o.pos = UnityObjectToClipPos(v.vertex);
                o.normal = v.normal;
                o.vertex = v.vertex;
                TRANSFER_SHADOW(o) // 使用预定义宏变换阴影坐标

                return o;
            }

            fixed4 frag (v2f i) : SV_Target
            {
                // 准备变量
                float3 n = UnityObjectToWorldNormal(i.normal);
                n = normalize(n);
                float3 l = WorldSpaceLightDir(i.vertex);
                l = normalize(l);
                float4 worldPos = mul(unity_ObjectToWorld, i.vertex);

                // Lambert光照
                fixed ndotl = saturate(dot(n, l));
                fixed4 color = _LightColor0 * _MainColor * ndotl;

                // 加上4个点光源的光照
                color.rgb += Shade4PointLights(
                unity_4LightPosX0, unity_4LightPosY0, unity_4LightPosZ0,
                unity_LightColor[0].rgb, unity_LightColor[1].rgb,
                unity_LightColor[2].rgb, unity_LightColor[3].rgb,
                unity_4LightAtten0, worldPos.rgb, n) * _MainColor;

                // 使用预定义宏计算阴影系数
                UNITY_LIGHT_ATTENUATION(shadowmask, i, worldPos.rgb)

                // 阴影合成
                color.rgb *= shadowmask;

                return color;
            }
            ENDCG
        }
    }
    FallBack "Diffuse"
}

7、使用Frame Debug分析渲染过程

学会使用Debug是每个程序员必须掌握的技术，当然图形学渲染也不例外，利用Unity中的Frame Debug工具可以让我们更加清晰的认识到unity渲染的步骤。具体步骤可以点击菜单栏Windows>Analysis>Frame Debugger

以上光照模型均利用顶点片段着色器来编写，我们会发现代码极其繁琐，不过请放心为了降低工作难度unity提供了表面着色器（Surface Shader）专门用于编写与灯光进行交互的Shader，在后续部分我们将直接利用表面着色器来使用这些光照模型。